Close

I2C shenanigans

A project log for Arduino Skillz

Week of Arduino

kendoken.do 01/31/2017 at 14:390 Comments

I want to use sensors. Probably more than one. So do you.

New to I2C (Inter-Integrated Circuit) communications, the best place to start was a simple sketch that looks for I2C devices/connections. Without knowing if your device/connection is recognized, you may be failing and not understanding why. Often I think that I have done something wrong to find out (much) later that a device or component is malfunctioning. This code shows it's results in the serial monitor when run.

// --------------------------------------
// i2c_scanner
//
// Version 1
//    This program (or code that looks like it)
//    can be found in many places.
//    For example on the Arduino.cc forum.
//    The original author is not know.
// Version 2, Juni 2012, Using Arduino 1.0.1
//     Adapted to be as simple as possible by Arduino.cc user Krodal
// Version 3, Feb 26  2013
//    V3 by louarnold
// Version 4, March 3, 2013, Using Arduino 1.0.3
//    by Arduino.cc user Krodal.
//    Changes by louarnold removed.
//    Scanning addresses changed from 0...127 to 1...119,
//    according to the i2c scanner by Nick Gammon
//    http://www.gammon.com.au/forum/?id=10896
// Version 5, March 28, 2013
//    As version 4, but address scans now to 127.
//    A sensor seems to use address 120.
// Version 6, November 27, 2015.
//    Added waiting for the Leonardo serial communication.
// 
//
// This sketch tests the standard 7-bit addresses
// Devices with higher bit address might not be seen properly.
//

#include <Wire.h>


void setup()
{
  Wire.begin();

  Serial.begin(9600);
  while (!Serial);             // Leonardo: wait for serial monitor
  Serial.println("\nI2C Scanner");
}


void loop()
{
  byte error, address;
  int nDevices;

  Serial.println("Scanning...");

  nDevices = 0;
  for(address = 1; address < 127; address++ ) 
  {
    // The i2c_scanner uses the return value of
    // the Write.endTransmisstion to see if
    // a device did acknowledge to the address.
    Wire.beginTransmission(address);
    error = Wire.endTransmission();

    if (error == 0)
    {
      Serial.print("I2C device found at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.print(address,HEX);
      Serial.println("  !");

      nDevices++;
    }
    else if (error==4) 
    {
      Serial.print("Unknow error at address 0x");
      if (address<16) 
        Serial.print("0");
      Serial.println(address,HEX);
    }    
  }
  if (nDevices == 0)
    Serial.println("No I2C devices found\n");
  else
    Serial.println("done\n");

  delay(5000);           // wait 5 seconds for next scan
}

Not only can you proceed with the sure knowledge your device is connecting, you will also know where it is connecting. The address of the device/module/connection is necessary in most sketches to make use of it.

I get a message like this:

****

Scanning...

I2C device found at address 0x68 !

done

****

One of the common issues with learning Arduino is not realizing that you need to make changes to most sketches to make them work. Read the comments, follow the tutorial exactly if there is a good one.

Sometimes it may be a good idea to make a physical list of the variables you will be using and the pins to which you want to connect. This way, when you are looking through the code, you can easily identfy potential issues.

Discussions