Build Instructions

Collapse

• 1

  Code

  Here is the code that works with our Adafruit and connects with the app which is linked in project files. 

  #include <WiFi.h>
  #include <HTTPClient.h>

  const char* ssid = "WIFI_NETWORK";
  const char* password = "";

  // Domain Name with full URL Path for HTTP POST Request
  const char* serverName = "http://api.thingspeak.com/update";
  // Service API Key
  String apiKey = "THE_API_KEY";

  unsigned long lastTime = 0;
  // Timer set to 15 seconds (15000)
  unsigned long timerDelay = 15000;

  // State of the sensor
  int state = 0;

  void setup() {
    Serial.begin(115200);

    pinMode(13, INPUT_PULLUP);

    WiFi.begin(ssid, password);
    Serial.println("Connecting");
    while(WiFi.status() != WL_CONNECTED) {
      delay(500);
      Serial.print(".");
    }
    Serial.println("");
    Serial.print("Connected to WiFi network with IP Address: ");
    Serial.println(WiFi.localIP());
   
    Serial.println("Timer set to 15 seconds (timerDelay variable), it will take 15 seconds before publishing the first reading.");
  }

  void loop() {
    //Send an HTTP POST request every 15 seconds
    if ((millis() - lastTime) > timerDelay) {
      //Check WiFi connection status
      if(WiFi.status()== WL_CONNECTED){
        WiFiClient client;
        HTTPClient http;
      
        // Domain name with URL path or IP address with path
        http.begin(client, serverName);
        
        // Specify content-type header
        http.addHeader("Content-Type", "application/x-www-form-urlencoded");
        
        // Data to send with HTTP POST
        state = digitalRead(13);
        // Change the "&field1" to POST to other fields
        String httpRequestData = "api_key=" + apiKey + "&field1=" + String(state);           
        // Send HTTP POST request
        int httpResponseCode = http.POST(httpRequestData);
        
        /*
        // If you need an HTTP request with a content type: application/json, use the following:
        http.addHeader("Content-Type", "application/json");
        // JSON data to send with HTTP POST
        String httpRequestData = "{\"api_key\":\"" + apiKey + "\",\"field1\":\"" + String(random(40)) + "\"}";           
        // Send HTTP POST request
        int httpResponseCode = http.POST(httpRequestData);*/
       
        Serial.print("HTTP Response code: ");
        Serial.println(httpResponseCode);
          
        // Free resources
        http.end();
      }
      else {
        Serial.println("WiFi Disconnected");
      }
      lastTime = millis();
    }
  }

• 2

  Wiring

  Each FeatherV2 needs a hall effect sensor plugged into GND and 3.3v, as well as the data pin plugged into digital pin 13.

View all instructions